%%HP: T(3)A(R)F(.);
DIR
  KMENU
  \<< { { "--K-\|>"
    \<< CLLCD "Tempor\228res Men\252
zum Justieren der
System-Uhr.
Siehe[INFO]!
www.praxelius.de
12.09.2011
(Anzeige beenden) \-> ON" 1. DISP 7. FREEZE
    \>> } { "INFO"
    \<< CLLCD "   Zeiteingabe:

Uhrzeit  hh.mmss
in den Stack stellen.
Dann \->genau\<- zu
diesem Zeitpunkt mit
[JETZT] starten." CLLCD 1. DISP 7. FREEZE
    \>> } { "JETZT"
    \<< CLLCD STD DEPTH
      IF 1. \>=
      THEN TIME \-> ts tu
        \<<
          CASE ts TYPE 0. \=/
            THEN 1000. .1 BEEP 2000. .1 BEEP "Keine Dezimalzahl!" MSGBOX
            END ts 0. <
            THEN 1000. .1 BEEP 2000. .1 BEEP "Keine g\252ltige
 Uhrzeit!
     Zahl < 0" MSGBOX
            END ts 24. \>=
            THEN 1000. .1 BEEP 2000. .1 BEEP "
Keine g\252ltige
 Uhrzeit!

 Stunde > 23" MSGBOX
            END ts FP 100. * IP 60. \>=
            THEN 1000. .1 BEEP 2000. .1 BEEP "
Keine g\252ltige
 Uhrzeit!

 Minute > 59" MSGBOX
            END ts FP 100. * FP 100. * IP 60. \>=
            THEN 1000. .1 BEEP 2000. .1 BEEP "
Keine g\252ltige
 Uhrzeit!
        
  Sekunde > 59" MSGBOX
            END TJUST TYPE 10. \=/
            THEN 1000. .1 BEEP 2000. .1 BEEP "
TJUST enth\228lt keine
 TICKS" MSGBOX
            END ts HMS\-> tu HMS\-> - 3600. * 'UHRKO' STO TICKS 
TJUST - B\->R 8192. / 3600. / 'STUND' STO UHRKO 
8192. * STUND / 6. * IP 'AFKO' STO CLLCD "Werte sind berechnet,
  anzeigen?   [WERTE]
Neue Berechnung?
  Neue Uhrzeit ein-
  geben, dann [JETZT]
Uhr korrigieren und
  justieren?   [KORR]" 1. DISP 7. FREEZE
          END
        \>>
      ELSE "Uhrzeitsollwert
  hh.mmss
   mu\Gb im
    untersten
     Stack
      stehen!" 1000. .2 BEEP MSGBOX
      END
    \>>
    \<<
    \>> } { "WERTE"
    \<< CLLCD 2. FIX "Korrektur-Werte
  f\252r System-Uhr:
 UHRKO = " UHRKO \->STR + " Sek.
 STUND = " + STUND \->STR + " Std.
 AFKO  = " + STD AFKO IP \->STR + " Ticks
 AF(alt) = " + AF IP \->STR + " Ticks" + DUP 'WERTE' STO STD 1. DISP 7. FREEZE
      \<< { WERTE AFKO STUND UHRKO LOE } PURGE
      \>> 'LOE' STO { LOE AFKO STUND UHRKO WERTE } ORDER
    \>> } { "KORR"
    \<< STUND
      IF 24. \>=
      THEN "Uhrzeit korrigiert:
UHRKO  = " 2. FIX UHRKO \->STR + " Sek.
       = " + STD UHRKO 8192. * IP DUP CLKADJ \->STR + " Ticks
Justierung angepasst:
AFKO   = " + STD AFKO \->STR + " Ticks
AF neu = " + AFKO 'AF' STO+ AF \->STR + 1. DISP 7. 
FREEZE TICKS 'TJUST' STO 0. 'STUND' STO
      ELSE 1000. .2 BEEP CLLCD "Justiert vor
" 2. FIX STUND \->STR + " Std.
Neujustierung
ist 24 Stunden
lang gesperrt!" + MSGBOX
      END
    \>> } { "CANCL"
    \<< 2.01 MENU
    \>> } } TMENU STD
  \>>
  ALM1 { 13.092011 6.
  \<< PATH { HOME JUST AF } EVAL CLKADJ EVAL DROP OFF
  \>> 176947200. }
  TJUST # 520053516960484d
  AF -4043.
END