%%HP: T(3)A(R)F(.);
DIR
@ Programm zur Berechnung des Taupunkts aus der relativen Luftfeuchte und der Lufttemperatur.
@ Das Programm ist im PDF-Dokument Luft.pdf beschrieben.
  LF
  \<< DEPTH
    IF 2. <
    THEN "Lufttemperatur
-20 bis 50\^oC und rel.
Luftfeuchte 
0 bis 100 %
eingeben" 1000. .2 BEEP 500. .1 BEEP MSGBOX
    ELSE 1 CF ABS 'LF%' STO 't' STO  t t2g DUP 'LFs' STO LF% * 100. / 'LFa' STO LFa g2t 'TauPT' STO 1. FIX "   Luftfeuchtigkeit
         (LF)
Lufttemp. = " t \->STR + " \^oC
LF relat. = " + LF% \->STR + " %
LF ges\228tt.= " + LFs \->STR + " g/m\179
LF absol. = " + LFa \->STR + " g/m\179
" +   IF 1 FS?C
      THEN "Keine Taupunktberechn." +
      ELSE IF TauPT 0. >
        THEN "Taupunkt  = " +
        ELSE "Reifpunkt = " +
        END TauPT \->STR + " \^oC" +
      END CLLCD 0. DISP 0. WAIT DROP
    END
  \>>
  t 0.
  LF% 0.
  LFs 4.952
  LFa 0.
  TauPT 0.
  LOE
  \<< 1 CF 0. { t LFs LF% LFa TauPT } STO
  \>>
  t2g
  \<<  \-> tt \<<CASE 
    tt 3.2144160197 < THEN tt 0.0788 * EXP 4.6962 * END
    tt 26.2312802589 < THEN tt .0623 * EXP 4.952 * END
    tt .0503 * EXP 6.784 *
    END 
  \>> \>>
  g2t
  \<< \-> a \<< CASE
    a 0. \<= THEN "Fehler!" 1 SF END
    a 0.5 < THEN a 4.6962 / LN 0.0788 / 1 SF END
    a 6.0499478575 < THEN a 4.6962 / LN 0.0788 / END
    a 25.3809856063 <  THEN a 4.952 / LN .0623 / END
    a 6.784 / LN .0503 /
    END 
  \>> \>>
END