%%HP: T(3)A(D)F(.);
@ Programm SATPEIL = Satellitenpeilung, 
@ (nicht im Verzeichnis HOME, sondern in einem Unterverzeichnis speichern).
@ Autor: Otto Praxl, www.praxelius.de
@ Fassung vom 08.11.2011
@ Das Programm ist im Buch des Autors
@  "Berechnungsgrundlagen für Amateurastronomen"
@  im Kapitel "Satellitenpeilung" mit allen Formeln beschrieben.
@ Eingabe: Orbitposition des Satelliten, z.B. 19.2 für Astra.
@ Ausgabe: Peilwinkel zum Satelliten vom Standort der Amtenne aus.
@ Voreingestellt sind: Geogr. Länge  Lg=11.57° Ost, 
@                      geogr. Breite Br=48.13° Nord.
@ Die Voreinstellungen für Lg und Br können im Programm geändert werden (siehe unten).
@ Andere Werte können in den im Menü angezeigten Variablen "Lg" und "Br" 
@ temporär eingespeichert werden (bis Lg und Br von Hand gelöscht werden).
@ Mit LOE können alle erzeugten Variablen (außer Lg und Br) gelöscht werden.
\<< DEG 2. FIX
  IF DEPTH 1. \>=
  THEN 'Orb' STO
  END
  IF 'Orb' VTYPE 0. ==
  THEN
@ Die Voreinstellung für Lg kann hier geändert werden:
    IF 'Lg' VTYPE -1. ==
    THEN 11.57 'Lg' STO
    END
@ Die Voreinstellung für Br kann hier geändert werden:
    IF 'Br' VTYPE -1. ==
    THEN 48.13 'Br' STO
    END
    IF Orb Lg - ABS 90. <
    THEN Orb Lg - 'Dif' STO Dif TAN NEG Br SIN
      IF DUP 0. \=/
      THEN / ATAN
      ELSE DROP DROP
        IF Dif 0. <
        THEN -90.
        ELSE 90.
        END
      END 'Azi' STO Br COS Dif COS * DUP ACOS 'b' STO
      IF DUP 1. \=/
      THEN DUP .151095846455 - SWAP ACOS SIN / ATAN 'Ele' STO
      ELSE DROP 90. 'Ele' STO
      END "Satellitenpeilung
Ort:     Lg = " Lg \->STR + "\^o
         Br = " + Br \->STR + "\^o
Orbit:   Orb= " + Orb \->STR + "\^o
Peilung: Azi= " + Azi \->STR + "\^o
         Ele= " + Ele \->STR + "\^o" +
      IF Ele 0. <
      THEN "
       nicht sichtbar!" +
      END CLLCD 1. DISP 0. WAIT DROP
      \<< { Ele Azi b Dif Orb LOE } PURGE
      \>> 'LOE' STO { LOE Lg Br Orb Azi Ele b Dif } ORDER
    ELSE 4000. .1 BEEP "Azimut > \17790\^o!
 Berechnung
 wird nicht
 durchgef\252hrt!" MSGBOX
    END
  ELSE 4000. .1 BEEP "Satelliten-Peilung:

 Angabe f\252r
 Orbitposition fehlt!

 Ost=(+)     West=(-)" CLLCD 1. DISP 0. WAIT DROP
  END
\>>